scufcont/meson.build

project(
  'scufcont',
  'c',
  version: '0.0.1',
  default_options: {
    'buildtype': 'release'
  }
)

cc = meson.get_compiler('c')

c_args = [
  '-std=c99',
  '-Wall',
  '-Wextra',
  '-pedantic'
]

cmocka_dep = dependency('cmocka')

scufcont_include = include_directories('include')

scufcont_lib = library(
  'scufcont',
  'src/DString.c',
  'src/scufcont.c',
  include_directories: [
    scufcont_include
  ],
  c_args: [
    c_args,
    '-D_SCUFCONT_VERSION="' + meson.project_version() + '"',
  ]
)

scufcont_dep = declare_dependency(
  compile_args: [
    c_args,
    '-D_SCUFCONT_VERSION="' + meson.project_version() + '"',
  ],
  include_directories: scufcont_include,
  link_with: scufcont_lib,
  version: meson.project_version()
)

if meson.is_subproject()
  meson.override_dependency('scufcont', scufcont_dep)
endif

if get_option('SCUFCONT_BUILD_TESTS') == true
  subdir('tests')
endif

darray_prepro = custom_target(
  'DArray_prepro',
  output: 'DArray_prepro.h',
  input: 'include/scufcont/DArray.h',
  command: [ cc.cmd_array(), c_args, '-E', '-o', '@OUTPUT@', '@INPUT@' ],
)